[Release] Newsbar

[d0h!]

Background:

PHP Code:

Create_Newsbar( Shader, Align, Alpha, Color, Speed ) 

//Example's ,
level thread Create_Newsbar(); // You don't have to define any option's for it to work there are defaults.
level thread Create_Newsbar( undefined, "BOTTOM", 50, ( 180, 0, 0 ) ); 


News Text:

PHP Code:

Set_Newsbartext( Text, Font, FontScale, Color, GColor, GAlpha )

//Example's ,
level thread Set_Newsbartext( "Welcome To ^4NITRAM's  ^7Modified  Warfare" ); // Now with this you can if you wont just define  the text.
level thread Set_Newsbartext( "Welcome To ^4NITRAM's  ^7Modified  Warfare", "HUDBIG", 1, ( 180, 0, 180 ), ( 180, 180, 0 ),  25 ); 


This function is for if you what to update the news text an example you just Kick/Verified someone, to use this you would just call it up anytime you want NewText is for what you want to update the text to and KeepOld is if you what it to display the old message again after to update.

PHP Code:

Update_Newsbar( NewText, KeepOld )

//Example's ,
level thread Update_Newsbar( "Welcome To ^4NITRAM's ^7Modified  Warfare  ^1only 30 minutes left!" ); // Won't keep the old message
level thread Update_Newsbar( player.name + " Has been kicked by " + self.name, true ); 


Code:

PHP Code:

Create_Newsbar( Shader, Align, Alpha, Color, Speed )
{
        News = spawnStruct();
        News.Text = newHudElem();
        News.Text.alignX = "CENTER"; 
        News.Text.horzAlign = "CENTER";
        News.Text.foreGround = true;    
        News.Text.hideWhenInMenu = true; 
        News.Text.Glow = 1;
        News.Text.Sort = 2; 
        News.Shader = newHudElem();
        News.Shader.horzAlign = "CENTER";
        News.Shader.alignX = "CENTER";
        News.Shader.foreGround = false;
        News.Shader.hideWhenInMenu = true;      
        News.Shader.Sort = 1;           
        News.Speed = 60;
        if( isDefined( Speed ) ) News.Speed = Speed;
        if( isDefined( Align ) )
        {
                News.Text.alignY = Align;
                News.Text.vertAlign = Align;
                News.Shader.alignY = Align;
                News.Shader.vertAlign = Align;
        }
        else
        {
                News.Text.alignY = "TOP";
                News.Text.vertAlign = "TOP";
                News.Shader.alignY = "TOP";
                News.Shader.vertAlign = "TOP";
        }
        if( isDefined( Alpha ) ) News.Shader.Alpha = Alpha;
        else News.Shader.Alpha = 0.75;
        if( ( !isDefined( Color ) ) && ( !isDefined( Shader ) ) ) Shader = "BLACK";
        if( isDefined( Shader ) ) News.Shader setShader( Shader, 0, 25 );
        if( ( isDefined( Color ) ) && ( !isDefined( Shader ) ) )
        {
                News.Shader.Color = Color;
                News.Shader setShader( "WHITE", 0, 25 );
                        
        }
        News.Shader scaleOverTime( 7, 880, 25 );
        wait 7;
        level notify( "Created_Newsbar", News );
        wait ( 0.05 );
}

Set_Newsbartext( Text, Font, FontScale, Color, GColor, GAlpha )
{
        level waittill( "Created_Newsbar", News );
        News.Message = Text;
        if( isDefined( Font ) ) News.Text.Font = Font;
        else News.Text.Font = "HUDBIG";
        if( isDefined( FontScale ) ) News.Text.FontScale = FontScale;
        else News.Text.FontScale = 1;
        if( isDefined( Color ) ) News.Text.Color = ( Color[0], Color[1], Color[2] );
        if( isDefined( GColor ) ) News.Text.GlowColor = ( GColor[0]/255, GColor[1]/255, GColor[2]/255 );
        if( isDefined( GAlpha ) ) News.Text.GlowAlpha = GAlpha;
        if( isDefined( Text ) ) News.Text setText( Text );
        else News.Text setText( "define your text dip****" );
        News.Text.x += ( Text.size + 870 ) * 1.45;
        News.TextSize = Text.size;
        for( ;; )
        {
                wait ( 0.05 );
                News.Text moveOverTime( ( ( News.TextSize + 870 ) / News.Speed ) );
                News.Text.x -= ( News.TextSize + 870 ) * 2.9;
                wait ( ( News.TextSize + 870 ) / News.Speed ) - 0.05;
                News.Text.x += ( News.TextSize + 870 ) * 2.9;
                level notify ( "Done_Message", News );
        }
}

Update_Newsbar( NewText, KeepOld )
{
        self endon( "Done_Update" );
        level waittill( "Done_Message", News );
        News.OldMessage = News.Message;
        News.OldTextSize = News.TextSize;
        News.OldSpeed = News.Speed;
        News.Text setText( "^1News Update : ^7" + NewText );
        News.TextSize = NewText.size;
        News.Speed = 100;
        level waittill( "Done_Message" );
        News.Speed = News.OldSpeed;
        if( isDefined( KeepOld ) && KeepOld )
        {
                News.Text setText( News.OldMessage );
                News.TextSize = News.OldTextSize;
        }
        else
        {
                News.Text setText( NewText );
                News.TextSize = NewText.size;
        }
        level notify( "Done_Update" );
} 


Credits:
Azumikkel (Original Code)
Nitram (edited)

[isokasi]

looks nice

[Killingdyl]

azu didnt make the original code

[d0h!]

it is the code azumikkel used in his RTD and this code got edited by nitram now.
and yes, i dont know who made the first script of it, probably someone in the time where cod4 was released

[alistair3149]

it is the code azumikkel used in his RTD and this code got edited by nitram now.
and yes, i dont know who made the first script of it, probably someone in the time where cod4 was released

It seems that u havent read other posts from 7, the xbox version of RTD which in youtube is a customize version by NITRAM, the newsbar is just testing, the true creator is NITRAM, and the original creator is Lost

[Ferrari]

How can get xbox buttoms all like that was?

[alistair3149]

How can get xbox buttoms all like that was?

If u can see that, thats a video of a mod in XBOX